aur-packages/deoplete-jedi-git/PKGBUILD

# Maintainer: Trent Palmer trenttdually at gmail

###########################################################################################################
#                                          Build Options
###########################################################################################################
_vim="y"

_neovim="y"
###########################################################################################################

_name='deoplete-jedi'
pkgname="${_name}-git"
pkgver=r228.0410de7
pkgrel=1
pkgdesc="jedi add-on for deoplete completion plugin for neovim"
arch=('any')
url="https://github.com/zchee/deoplete-jedi"
license=('MIT')
groups=()
depends=('deoplete-git' 'python-jedi' 'python2-jedi')
makedepends=('git') 
provides=('deoplete-jedi')
conflicts=('deoplete-jedi')
replaces=()
backup=()
options=()
source=("${_name}::${url//https/git}")
noextract=()
md5sums=('SKIP')

pkgver() {
    cd "${srcdir}/${_name}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

# hack server.py so it doesn't source jedi and parso submodules
prepare() {
    cd "${srcdir}/${_name}/rplugin/python3/deoplete/sources/deoplete_jedi/"
    sed -i -e 's/vendored//g' server.py
}

package() {
  if [ "$_neovim" = "y" ]; then
    mkdir -p "$pkgdir/usr/share/nvim/runtime/rplugin/python3/deoplete"
    cp -r "${srcdir}/${_name}/rplugin/python3/deoplete/sources" \
      "$pkgdir/usr/share/nvim/runtime/rplugin/python3/deoplete/"
  fi

  if [ "$_vim" = "y" ]; then
    mkdir -p "$pkgdir/usr/share/vim/vimfiles/rplugin/python3/deoplete"
    cp -r "${srcdir}/${_name}/rplugin/python3/deoplete/sources" \
      "$pkgdir/usr/share/vim/vimfiles/rplugin/python3/deoplete/"
  fi

    install -D -m644 "${srcdir}/${_name}/README.md" $pkgdir/usr/share/doc/$pkgname/README.md
    install -D -m644 "${srcdir}/${_name}/LICENSE" $pkgdir/usr/share/licenses/$pkgname/LICENSE
}